Systems Management

32-bit install from Startup Script fails on 64-bit machines

I'm having the same problem trying to silent install 32bit JRE 6 Update 17 on Windows 7 x64
using the system account. No problem when running installation script with admin account.
Did someone find a solution for it?

Thanks in advance!

Just a stab in the dark, I'm not that experienced with 64-bit systems..

Check if your files happen to be in c:\Documents and Settings\Default User\ instead of C:\Windows\system32\config\systemprofile\

If so it means a property in your MSI is being set wrong. Check the installer's Custom Actions to see if there's a distinction made betwwen x32 and x64 UserProfiles

I never did solve it, but I only used the script when I didn't know how to make the Static install work with a GPO software install. As of yesterday, I do, so I won't be using the Startup Script any more. If that's what you'd prefer, too, click here for the solution:

http://itninja.com/question/gnu,-freeware-and-shareware-programs-to-cloning6123

Firstly, I am a new-bee to posting, so please forgive me if I've done anything wrong here (direction/advice is welcome).
I know it's been a long time since the last post but it seems that this issue is still around with the new version of JRE. I have used the batch file deployment method and employed a little registry alteration to get around the issue of the SYSTEM account's lack of cooperation installing the 32-bit JRE on a 64-bit client. I found a batch file which got me part of the way but here's the full version with the registry change that allows both 64-bit & 32-bit installation to work. I will also include the text file afterwards that's used for uninstalling older versions of the JRE (jre-uninstall-list.txt), please be aware that the GUID list may not be complete but remarks in the batch file point you to a way of collecting GUIDs for older versions.

filename: jre-install.cmd
---------------------------------------------------------------
@echo off
set newjava32=jre-6u27-windows-i586-s.exe
set newjava64=jre-6u27-windows-x64.exe
set javasoftwarepath=\\myserverordomain.local\Software Repository\Applications\Sun\Java
cd "%systemdrive%\LOCAL DATA\Software\Installs\Sun\Java"

echo Determine 32bit or 64bit OS installation
Set RegQry=HKLM\Hardware\Description\System\CentralProcessor\0
REG.exe Query %RegQry% > checkOS.txt
Find /i "x86" < CheckOS.txt > StringCheck.txt
If %ERRORLEVEL% == 0 (
set ostype=32
) ELSE (
set ostype=64
)


echo Creating local software repository folder
if not exist "%systemdrive%\LOCAL DATA\Software\Installs\Sun\Java" md "%systemdrive%\LOCAL DATA\Software\Installs\Sun\Java"


echo Removing previous JRE versions - the GUIDs for previous versions must be entered in the jre-uninstall-list.txt file
rem GUIDs can be found for the older versions by searching the registry on PCs the old version's installed on
rem search in "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall" for the word "java" the version and GUID info should be indicated
xcopy "%javasoftwarepath%\jre-uninstall-list.txt" "%systemdrive%\LOCAL DATA\Software\Installs\Sun\Java" /D /I /Y
for /f %%a in (jre-uninstall-list.txt) do MsiExec.exe /uninstall %%a /quiet


echo Installing current JRE version
if %ostype% == 32 goto 32bit


echo Prepare registry key value for a Sun installer glitch - we'll fix it at the end
reg export "HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows NT\CurrentVersion\ProfileList\S-1-5-18" "%systemdrive%\LOCAL DATA\Software\Installs\Sun\Java\wowprofile.reg" /y
reg add "HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows NT\CurrentVersion\ProfileList\S-1-5-18" /V ProfileImagePath /T reg_expand_sz /d "%systemroot%\syswow64\config\systemprofile" /f

echo Populate the local installation package folder
if not exist "%systemdrive%\LOCAL DATA\Software\Installs\Sun\Java\%newjava64%" copy "%javasoftwarepath%\%newjava64%" "%systemdrive%\LOCAL DATA\Software\Installs\Sun\Java\%newjava64%"
"%systemdrive%\LOCAL DATA\Software\Installs\Sun\Java\%newjava64%" /qn /s AgreeToLicense=YES REBOOT=ReallySuppress JAVAUPDATE=0 AUTOUPDATECHECK=0 JU=0
ping localhost -n 5 >nul


:32bit
if not exist "%systemdrive%\LOCAL DATA\Software\Installs\Sun\Java\%newjava32%" copy "%javasoftwarepath%\%newjava32%" "%systemdrive%\LOCAL DATA\Software\Installs\Sun\Java\%newjava32%"
"%systemdrive%\LOCAL DATA\Software\Installs\Sun\Java\%newjava32%" /qn /s AgreeToLicense=YES REBOOT=ReallySuppress JAVAUPDATE=0 AUTOUPDATECHECK=0 JU=0


echo Removing Java update scheduler
reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run" /v SunJavaUpdateSched /f


echo Stopping Java QuickStarter Service
net stop JavaQuickStarterService
ping localhost -n 10 >nul


echo Removing Java QuickStarter Service
sc delete JavaQuickStarterService

echo Put the registry change we made earlier back to what it was
if %ostype% == 64 regedit /s "%systemdrive%\LOCAL DATA\Software\Installs\Sun\Java\wowprofile.reg"

---------------------------------------------------------------

filename: jre-uninstall-list.txt
---------------------------------------------------------------
{3248F0A8-6813-11D6-A77B-00B0D0150000}

{3248F0A8-6813-11D6-A77B-00B0D0150030}

{3248F0A8-6813-11D6-A77B-00B0D0150060}

{3248F0A8-6813-11D6-A77B-00B0D0150090}

{3248F0A8-6813-11D6-A77B-00B0D0150100}

{3248F0A8-6813-11D6-A77B-00B0D0150110}

{3248F0A8-6813-11D6-A77B-00B0D0160010}

{3248F0A8-6813-11D6-A77B-00B0D0160020}

{3248F0A8-6813-11D6-A77B-00B0D0160030}

{3248F0A8-6813-11D6-A77B-00B0D0160040}

{3248F0A8-6813-11D6-A77B-00B0D0160050}

{3248F0A8-6813-11D6-A77B-00B0D0160060}

{3248F0A8-6813-11D6-A77B-00B0D0160070}

{26A24AE4-039D-4CA4-87B4-2F83216010FF}

{26A24AE4-039D-4CA4-87B4-2F83216011FF}

{26A24AE4-039D-4CA4-87B4-2F83216013FF}

{26A24AE4-039D-4CA4-87B4-2F83216014FF}

{26A24AE4-039D-4CA4-87B4-2F83216015FF}

{26A24AE4-039D-4CA4-87B4-2F83216016FF}

{26A24AE4-039D-4CA4-87B4-2F83216017FF}

{26A24AE4-039D-4CA4-87B4-2F83216018FF}

{26A24AE4-039D-4CA4-87B4-2F83216019FF}

{26A24AE4-039D-4CA4-87B4-2F83216020FF}

{26A24AE4-039D-4CA4-87B4-2F83216021FF}

{26A24AE4-039D-4CA4-87B4-2F83216022FF}

{26A24AE4-039D-4CA4-87B4-2F86416021FF}

{26A24AE4-039D-4CA4-87B4-2F86416023FF}

{26A24AE4-039D-4CA4-87B4-2F86416024FF}

{26A24AE4-039D-4CA4-87B4-2F86416025FF}

{26A24AE4-039D-4CA4-87B4-2F86416026FF}

{26A24AE4-039D-4CA4-87B4-2F86416026F0}

---------------------------------------------------------------

I hope this helps someone out there.

Hello,

  After a week I manage to find the resolution to this problem.
Instead of using .exe file use the MSI file and the following command:

         

 WSHShell.Run  "msiexec.exe /i "+Path32+" /quiet",0,true

Path32= the path to may MSI file.
It will work for sure.
I`ve test it.

Using this command I manage to create a start-up script that will look at my PC`s and if there is java 32 or 64 bits on the PC:
   Then:  it will check if is the latest version and install the latest version if necessary.
    Else: if no java do nothing.
Plus it generates a log file to give me some info about the old java version, before update.

I hope you will find useful this info.

Thanks,
Daniel