Software Deployment

Without installing the MSI you can use Orca, a free download from Microsoft contained in the Platform SDK.  It is the tool they use to create, edit MSI files.  Once you open the MSI with Orca look in the Properties Table and look for the Prodcut ID which is the GUID you are looking for.

You can use something like this which I've quickly knowcked up.  Paste it into a file, say uninstallString.vbs. Usage is:

Open a CMD prompt

Type: Cscript uninstallString.vbs <path to root folder containing all MSIs)

Things to do:

Error trapping

Write results to log file instead of CMD prompt

Retrieve Product Name?

The Script:

 Set objFSO = CreateObject("Scripting.FileSystemObject")

'set this to the root folder which contains all the MSIs in subfolders
objStartFolder = wscript.arguments(0)

Set objFolder = objFSO.GetFolder(objStartFolder)

Set colFiles = objFolder.Files
For Each objFile in colFiles
    wscript.echo objFile.Path
    wscript.echo GetProductCode(objFile.Path)
Next
Wscript.Echo

ShowSubfolders objFSO.GetFolder(objStartFolder)

Sub ShowSubFolders(Folder)
    For Each Subfolder in Folder.SubFolders
        Set objFolder = objFSO.GetFolder(Subfolder.Path)
        Set colFiles = objFolder.Files
        For Each objFile in colFiles
             wscript.echo objFile.Path
             wscript.echo GetProductCode(objFile.Path)
        Next
        Wscript.Echo
        ShowSubFolders Subfolder
    Next
End Sub

Function GetProductCode(ByVal msiPath)

    Const msiOpenDatabaseModeReadOnly = 0
    Dim msi, db, view

    Set msi = CreateObject("WindowsInstaller.Installer")
    Set db = msi.OpenDataBase(msiPath, msiOpenDatabaseModeReadOnly)
    Set view = db.OpenView("SELECT `Value` FROM `Property` WHERE `Property` = 'ProductCode'")
    view.Execute()

    GetProductCode = "MSIEXEC /X " & view.Fetch().StringData(1) & " /QN"

End Function

I'm sure you could do it with a script, but what I usually do is look in the registry where the Add Remove Programs (ARP) data is at

HKEY_LOCAL_MACHINESOFTWAREMicrosoftWindowsCurrentVersionUninstall 

Do a search from here for your software name or just browse through-- the subkey for each product is it's GUID (at least for all the MSI setups).

I think I have a workaround that has nothing to do with MSIs but would still like to find out this info

a VBScript will do it but for each MSI the script should be run on each MSI atleast once to get the GUID