x64 MSI contains x86 Flash Player as well. Hence, there is no need to download BOTH x86 AND x64 if you're installing on x64.

I wrote this script to check the version of Adobe Flash you are using, if it's out of date, then update your version of Flash based on if you are using 32 bit or 64 bit version of Windows 7 and Vista (Haven't tested on XP). Also, silent installs. I modified the MSI files using Orca to disable auto updates and anything else it would prompt for. It also logs the install process in case anything goes wrong. I'm sure you could add some lines to clean up the registry and also uninstall an older version before installing over the top, but this works just fine for my current needs.

 @ECHO off
:: Must change the first 3 variables when updating Adobe Flash version...
SET AdobeInstaller=install_flash_player_11_active_x_32bit.msi
SET AdobeInstallerx64=install_flash_player_11_active_x_64bit.msi
SET VersionCheck=11.2.202.235
:: Must change the first 3 variables when updating Adobe Flash version...
SET LOGDIR=C:\Software
SET AdobeLogFile=%LOGDIR%\AdobeUpdate11_2.txt
SET MSILOGFILE=%1
IF NOT EXIST %LOGDIR% MKDIR %LOGDIR%

:32BitCheck
:: Checks to see if the 32 bit Reg Key exist.
SET RegKey=HKLM\SOFTWARE\Macromedia\FlashPlayerActiveX
REG QUERY %RegKey% >NUL && GOTO :RegistryCheck

:64BitCheck
SET RegKey=HKLM\SOFTWARE\Wow6432Node\Macromedia\FlashPlayerActiveX
REG QUERY %RegKey% >NUL && GOTO :RegistryCheck
GOTO :InstallAdobeFRESH

:RegistryCheck
SET "AdobeVersion=" & setlocal & Set "$V="
:: Look in the Uninstall area of registry, where the installed version of Flash player is listed.
SET "RegItem=Version"
:: Take the output of a REG QUERY to the location above, and put it into the AdobeVersion variable / compairing VersionCheck.
For /f "tokens=3*" %%! in (
   '2^>nul Reg.exe QUERY "%RegKey%" /v "%RegItem%" ^|(
   Findstr.exe /ri "\<%RegItem%\>"^)') Do Set "$V=%%!"
endlocal & call Set "AdobeVersion=%$V%"
GOTO :InstallAdobe
:InstallAdobe
:: Checks to see if current version of Adobe Flash is installed.
IF {%AdobeVersion%} EQU {%VersionCheck%} GOTO :INSTALLED
GOTO :CPUCheck

:CPUCheck
:: Checks for 32 or 64 bit architecture.
ECHO Begining Adobe Flash %VersionCheck% install / update process > %adobelogfile%
ECHO Checking for Processor Type >> %adobelogfile%
IF {%PROCESSOR_ARCHITECTURE%} NEQ {x86} GOTO :x64Install
IF {%PROCESSOR_ARCHITEW6432%} EQU {AMD64} GOTO :x64Install

:X86Install
:: Installs 32 bit Adobe Flash.
ECHO x86 type found. >> %adobelogfile%
ECHO Installing Adobe Flash %VersionCheck% 32 Bit. >> %adobelogfile%
start /wait msiexec.exe /qn /i %AdobeInstaller% /lv* "%MSILOGFILE%"
ECHO Adobe Flash %VersionCheck% 32 Bit has been sucessfully installed. >> %adobelogfile%
GOTO :END

:X64Install
:: Installs 64 bit Adobe Flash.
ECHO x64 type found. >> %adobelogfile%
ECHO Installing Adobe Flash %VersionCheck% 64 Bit. >> %adobelogfile%
start /wait msiexec.exe /qn /i %AdobeInstallerx64%  /lv* "%MSILOGFILE%"
ECHO Adobe Flash %VersionCheck% 64 Bit has been sucessfully installed. >> %adobelogfile%
GOTO :END

:INSTALLED
ECHO Adobe Flash %VersionCheck% is already installed. >> %adobelogfile%
GOTO :END

:END
ECHO End of installation process. >> %adobelogfile%

Go to this link "http://www.adobe.com/products/flashplayer/distribution3.html". In the web page it gives you the option to download an EXE/MSI

The 11.4.402.265 msi seems to support the ISCECKFORPRODUCTUPDATES=2 public property value to turn off automatic updates.

Here I published a tutorial for it and many others programs. Please comment on the blog if you have questions.

http://it-grund.blogspot.com/2012/04/how-to-deployinstall-silently-and.html

x64 MSI contains x86 Flash Player as well. Hence, there is no need to download BOTH x86 AND x64 if you're installing on x64.